@ECHO OFF
:: Save or rename this file extension as MakeMM21.BAT not MakeMM21.txt to use.

IF '%1'=='~' GOTO ~
IF EXIST moviemk.ch? GOTO Step1
IF EXIST MUI\NUL IF EXIST Wmm2ae.dll GOTO Step3

ECHO Install Movie Maker 2.1 from WinXP-SP2 or a cancelled SP2 Setup
ECHO ___________________________
ECHO.
ECHO Exiting... Unable to detect your desired operation:
ECHO 1. To create \MM21INF, run me from inside %windir%\ServicePackFiles\I386
ECHO '  or %windir%\I386 on WinXP-SP2, or from inside the temporary extract
ECHO '  folder from WindowsXP-KB835935-SP2-ENU.exe then cancel SP2 Setup
ECHO 2. In Safe-Mode (F8 on boot) right-click MOVIEMK.INF and choose Install
ECHO 3. Run me again from inside Movie Maker folder to register new v2.1 DLLs
ECHO.
ECHO \MM21INF is a basic install that needs Windows Media Format 9 Series SDK
ECHO runtime (WMFdist.exe or MM20ENU.exe) and Microsoft add directX 9.0c or later
ECHO.
ECHO Step 1 needs 18 files:
ECHO blank.txt empty.txt filters.xm? moviemk.ch? moviemk.ex? moviemk.in? news.pn?
ECHO paint.pn? sample1.jp? sample2.jp? wmm2ae.dl? wmm2eres.dl? wmm2ext.dl?
ECHO wmm2filt.dl? wmm2fxa.dl? wmm2fxb.dl? wmm2res.dl? wmm2res2.dl?
ECHO.
ECHO THIS BATCH FILE HAS NOT BEEN WIDELY TESTED. GREAT CARE WAS TAKEN TO ENSURE
ECHO THAT THIS BATCH FILE PERFORMS AS IT SHOULD. IT IS PROVIDED 'AS IS', BY USING
ECHO THIS BATCH FILE, YOU AGREE TO USE IT AT YOUR OWN RISK.
PAUSE
GOTO End
:: v2 - Revised detection of Step 3 away from the wmmres.dll recreated by MM2.
:: v3 - Revised to add SP2 flexibility and about Windows Media Format SDK...
::      http://go.microsoft.com/fwlink/?LinkId=18502  and  LinkId=30589
:: v4 - Revised to add error-trapping to CALL'd extraction routine below.

:~
:: Routine to either expand or binary copy the source file passed
IF NOT EXIST %dest%\%4NUL MD %dest%\%4
IF NOT '%2'=='~' IF EXIST %2 EXPAND %2 %dest%\%4%3
IF EXIST %3 COPY %3 %dest%\%4%3 /B/Y
IF EXIST %dest%\%4%3 GOTO End
ECHO Error - Missing source for %3 press any key to continue...
PAUSE >NUL
GOTO End

:Step1
:: Extract files in list from SP2 temporary folder into \MM21INF
SET dest=%SystemDrive%\MM21INF
CALL %0 ~ MOVIEMK.IN_  moviemk.inf
CALL %0 ~ MOVIEMK.EX_  moviemk.exe I386\
CALL %0 ~ WMM2AE.DL_   WMM2AE.dll
CALL %0 ~ WMM2EXT.DL_  WMM2EXT.dll
CALL %0 ~ WMM2FILT.DL_ WMM2FILT.dll
CALL %0 ~ WMM2FXA.DL_  WMM2FXA.dll
CALL %0 ~ WMM2FXB.DL_  WMM2FXB.dll
CALL %0 ~ WMM2RES.DL_  WMM2RES.dll
CALL %0 ~ WMM2ERES.DL_ WMM2ERES.dll
CALL %0 ~ WMM2RES2.DL_ WMM2RES2.dll
CALL %0 ~ ~            Empty.txt
CALL %0 ~ FILTERS.XM_  Filters.xml
CALL %0 ~ NEWS.PN_     news.png
CALL %0 ~ PAINT.PN_    paint.png
CALL %0 ~ SAMPLE1.JP_  Sample1.jpg
CALL %0 ~ SAMPLE2.JP_  Sample2.jpg
CALL %0 ~ ~            Blank.txt
CALL %0 ~ MOVIEMK.CH_  moviemk.chm I386\
CD %dest%
ECHO Files extracted to %dest%, right-click moviemk.inf in Step 2
SET dest=
GOTO End

:Step3
:: Having installed MM21, register its DLLs
ECHO ON
FOR %%F IN (Wmm2ae.dll Wmm2ext.dll Wmm2filt.dll Wmm2fxa.dll Wmm2fxb.dll) DO RegSvr32 /S %%F
START moviemk.exe /RegServer

:End